import org.jetbrains.kotlin.konan.properties.Properties
import java.io.ByteArrayOutputStream
import java.io.FileInputStream

plugins {
    alias(libs.plugins.android.application)
    alias(libs.plugins.kotlin.android)
    alias(libs.plugins.kotlin.compose)
    alias(libs.plugins.hilt.android)
    alias(libs.plugins.ksp)
    alias(libs.plugins.kotlin.serialization)
}

android {
    namespace = "moe.tabidachi.emulator"
    compileSdk = 35

    defaultConfig {
        applicationId = "moe.tabidachi.emulator"
        minSdk = 23
        targetSdk = 28
        versionCode = 2
        versionName = "1.1-${getGitHash()}"

        ndk {
            abiFilters.add("armeabi-v7a")
        }
    }
    signingConfigs {
        val properties = Properties().apply {
            load(FileInputStream(project.rootProject.file("keystore.properties")))
        }
        create("release") {
            storeFile = file(properties.getProperty("signing.storeFile"))
            storePassword = properties.getProperty("signing.storePassword")
            keyAlias = properties.getProperty("signing.keyAlias")
            keyPassword = properties.getProperty("signing.keyPassword")
            enableV1Signing = true
            enableV2Signing = true
            enableV3Signing = true
            enableV4Signing = true
        }
    }
    buildTypes {
        release {
            isMinifyEnabled = true
            proguardFiles(
                getDefaultProguardFile("proguard-android-optimize.txt"), "proguard-rules.pro"
            )
            signingConfig = signingConfigs.getByName("release")
        }
        debug {
            isMinifyEnabled = false
            proguardFiles(
                getDefaultProguardFile("proguard-android-optimize.txt"), "proguard-rules.pro"
            )
            signingConfig = signingConfigs.getByName("release")
        }
    }
    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_11
        targetCompatibility = JavaVersion.VERSION_11
    }
    kotlinOptions {
        jvmTarget = "11"
    }
    buildFeatures {
        compose = true
    }
    applicationVariants.all {
        outputs.map { it as com.android.build.gradle.internal.api.BaseVariantOutputImpl }
            .forEach { output ->
                val outputFileName = "Emulator-${versionName}-${baseName}.apk"
                output.outputFileName = outputFileName
            }
    }
    lint {
        baseline = file("lint-baseline.xml")
    }
}

dependencies {
    implementation(libs.androidx.core.ktx)
    implementation(libs.androidx.appcompat)
    implementation(platform(libs.androidx.compose.bom))
    implementation(libs.androidx.ui)
    implementation(libs.androidx.ui.graphics)
    implementation(libs.androidx.ui.tooling.preview)
    implementation(libs.androidx.tv.material)
    implementation(libs.androidx.lifecycle.runtime.ktx)
    implementation(libs.androidx.activity.compose)
    implementation(project(":core"))
    implementation(project(":ui"))
    // hilt
    implementation(libs.hilt.android)
    ksp(libs.hilt.compiler)
    // navigation
    implementation(libs.hilt.navigation.compose)
    implementation(libs.compose.navigation)
    implementation(libs.kotlin.serialization)
    implementation(libs.datastore)
    implementation(libs.material.icons.extended)
    // ktor
    implementation(libs.ktor.client.core)
    implementation(libs.ktor.client.cio)
    implementation(libs.ktor.client.content.negotiation)
    implementation(libs.ktor.serialization.kotlinx.json)
    implementation(libs.ktor.client.logging)
    // coil
    implementation(libs.coil.compose)
    implementation(libs.coil.network.ktor3)
    // work
    implementation(libs.work.runtime.ktx)
    // room
    implementation(libs.androidx.room.ktx)
    ksp(libs.androidx.room.compiler)

    androidTestImplementation(platform(libs.androidx.compose.bom))
    androidTestImplementation(libs.androidx.ui.test.junit4)
    debugImplementation(libs.androidx.ui.tooling)
    debugImplementation(libs.androidx.ui.test.manifest)
    testImplementation(kotlin("test"))
    testImplementation(libs.junit)
    androidTestImplementation(libs.androidx.junit)
    androidTestImplementation(libs.androidx.espresso.core)
}

fun getGitHash(): String {
    return ByteArrayOutputStream().use {
        project.exec {
            commandLine("git", "rev-parse", "--short", "HEAD")
            standardOutput = it
        }
        it.toByteArray().let(::String).trim()
    }
}